航空公司管理信息系统
一个正常营运的航空公司需要管理所拥有的飞机、航线的设置、客户的信息等，更重要的还要提供票务管理。面对各种不同种类的信息，需要合理的数据库结构来保存数据信息以及有效的程序结构支持各种数据操作的执行。
本设计讲述如何建立一个航空公司管理信息系统。一般而言，航空公司的管理信息系统应该包括人事、工资管理模块 。
1 系统设计
1.1 系统功能分析
系统开发的总体任务是实现各种信息的系统化、规范化和自动化。
系统功能分析是在系统开发的总体任务的基础上完成。本例子中的航空公司管理信息系统需要完成功能主要有：
舱位信息的输入和修改，包括舱位等级编号、舱位等级名称、提供的各种服务类别，以及备注信息等。
客机信息的输入、修改和查询，包括客机编号、客机型号、购买时间、服役时间、经济舱座位数量、公务舱座位数量、头等舱座位数量以及备注信息等。
航线信息的输入、修改和查询，包括航线编号、出发城市、到达城市、航班日期、出发时间、到达时间、客机编号、经济舱价格、公务舱价格、头等舱价格和备注信息等。
客户等级信息的输入、修改，包括客户等级编号、客户等级名称、折扣比例和备注信息等。
客户信息的输入、修改和查询，包括客户编号、客户姓名、客户性别、身份证号码、联系电话、客户类型和备注信息等。
订票信息的输入、查询和修改，包括订票编号、客户编号、客户姓名、客户类型、折扣比例、航线编号、出发城市、到达城市、出发时间、舱位类型、票价、结算金额和备注信息等。
1.2 系统功能模块设计
对上述各项功能进行集中、分块，按照结构化程序设计的要求，得到如图9-1所示的系统功能模块图。

图9-1 系统功能模块图
2 数据库设计
数据库在一个信息管理系统中占有非常重要的地位，数据库结构设计的好坏将直接对应用系统的效率以及实现的效果产生影响。合理的数据库结构设计可以提高数据存储的效率，保证数据的完整和一致。
设计数据库系统时应该首先充分了解用户各个方面的需求，包括现有的以及将来可能增加的需求。数据库设计一般包括如下几个步骤：
数据库需要分析。
数据库概念结构设计。
数据库逻辑结构设计。
2.1 数据库需求分析
用户的需求具体体现在各种信息的提供、保存、更新和查询，这就要求数据库结构能充分满足各种信息的输出和输入。收集基本数据、数据结构以及数据处理的流程，组成一份详尽的数据字典，为后面的具体设计打下基础。
仔细分析调查有关航空公司管理信息需求的基础上，将得到如图9-2所示的本系统所处理的数据流程。

图9-2 航空公司管理信息系统数据流程图
针对一般航空公司管理信息系统的需求，通过对航空公司管理工作过程的内容和数据流程分析，设计如下面所示的数据项和数据结构：
舱位等级信息，包括的数据项有：舱位等级编号、舱位等级名称、是否有礼品、是否有报纸、是否有饮料、是否有午餐、是否有电影、是否可以改签、是否可以退票、是否可以打折、备注信息等。
客机信息，包括的数据项有：客机编号、客机型号、购买时间、服役时间、经济舱座位数量、公务舱座位数量、头等舱座位数量、备注信息等。
航线信息，包括的数据项有：航线编号、出发城市、到达城市、航班日期、出发时间、到达时间、客机编号、经济舱价格、公务舱价格、头等舱价格、备注信息等。
客户类型信息，包括的数据项有：客户类型编号、客户类型名称、折扣比例、备注信息等。
客户信息，包括的数据项有：客户编号、客户姓名、客户性别、身份证号码、联系电话、客户类型、备注信息等。
订票信息，包括的数据项有：订票编号、顾客编号、顾客姓名、顾客类型、折扣比例、航线编号、出发城市、到达城市、舱位类型、机票价格、结算金额、备注信息等。

有了上面的数据结构、数据项和数据流程，我们就能进行下面的数据库设计。
2.2 数据库概念结构设计
得到上面的数据项和数据结构以后，就可以设计出能够满足用户需求的各种实体，以及它们之间的关系，为后面的逻辑结构设计打下基础。这些实体包含各种具体信息，通过相互之间的作用形成数据的流动。
本实例根据上面的设计规划出的实体有：舱位等级信息实体、客机信息实体、航线信息实体、客户类型信息实体、客户信息实体、订票信息实体。各个实体具体的描述E-R图如下。
舱位等级信息实体E-R图如图9-3所示。

图9-3 舱位等级信息实体E-R图
客机信息实体E-R图如图9-4所示。

图9-4 客机信息实体E-R图
航线信息实体E-R图如图9-5所示。

图9-5 航线信息实体E-R图
客户类型信息实体E-R图如图9-6所示。

图9-6 客户类型信息实体E-R图
客户信息实体E-R图如图9-7所示。

图9-7 客户信息实体E-R图
订票信息实体E-R图如图9-8所示。

图9-8 订票信息实体E-R图
实体之间关系的E-R图如图9-9所示。

图9-9 实体之间关系的E-R图
2.3 数据库逻辑结构设计
现在需要将上面的数据库概念结构转化为SQL Server 2000数据库系统所支持的实际数据模型，也就是数据库的逻辑结构。
航空公司管理信息系统数据库中各个表格的设计结果如下面表格所示。每个表格表示在数据库中的一个表。表9-1为供应商信息表。
表9-1                        serviceInfo 舱位等级信息表
列  名 数据类型  可否为空  说  明
serviceNO  char NOT NULL 舱位等级编号
serviceName  nvarchar NULL 舱位等级名称
noPresent  char NULL 是否有礼物
noNewsPaper  char  NULL 是否有报纸
noDrink  char  NULL 是否有饮料
noFood  char  NULL 是否有午餐
noMovie  char  NULL 是否有电影
canChange  char  NULL 是否可以改签
canCancel  char  NULL 是否可以退票
canDiscount  char  NULL 是否可以打折
serviceMemo  text  NULL 备注信息
表9-2为顾客信息表格。
表9-2                        planeInfo客机信息表格
列  名 数据类型  可否为空  说  明
planeNO  char NOT NULL 客机编号
planeType  char NULL 客机型号
buyDate  datetime NULL 购买日期
serveDate  datetime  NULL 服役日期
isCommon  nvarchar  NULL 经济舱座位数量
isCommercial  nvarchar  NULL 公务舱座位数量
isFirst  nvarchar  NULL 头等舱座位数量
planeMemo  text  NULL 备注信息
表9-3为航线信息表。
表9-3                        airlineInfo航线信息表
列  名 数据类型 可否为空 说  明
airlineNO  char NOT NULL 航线编号
departCity  nvarchar NULL 出发城市
arrivalCity  nvarchar NULL 到达城市
departDate  char NULL 航班日期
departTime  char NULL 出发时间
arrivalTime  char NULL 到达时间
planeNO  char NULL 客机编号
commonPrice  numeric NULL 经济舱价格
commercialPrice  numeric NULL 公务舱价格
firstPrice  numeric NULL 头等舱价格
airlineMemo  text NULL 备注信息
表9-4为客户类型信息表格。
表9-4                      customerType 客户类型信息表
列  名 数据类型  可否为空  说  明
ctypeNO  char NOT NULL 客户类型编号
ctypeName  char  NULL 客户类型名称
discount  numeric  NULL 折扣比例
续表
列  名 数据类型  可否为空  说  明
ctypeMemo  text  NULL 备注
表9-5为客户信息表格。
表9-5                        customerInfo 客户信息表
列  名 数据类型  可否为空  说  明
customerNO  char NOT NULL 客户编号
customerName  char  NULL 客户姓名
customerSex  char  NULL 客户性别
customerID  char  NULL 身份证号码
customerTele  char  NULL 客户联系电话
customerType  char  NULL 客户类型
customerMemo  text  NULL 备注
表9-6为订票信息表格。
表9-6                        ticketInfo 订票信息表
列  名 数据类型  可否为空  说  明
ticketNO  char NOT NULL 订票编号
customerNO  char  NULL 客户编号
customerName  char  NULL 客户姓名
customerType  char  NULL 客户类型
discount  numeric  NULL 折扣比例
airlineNO  char  NULL 航线编号
departCity  nvarchar  NULL 出发城市
arrivalCity  nvarchar  NULL 到达城市
ticketDate  datetime  NULL 出发日期
serviceType  char  NULL 舱位类型
ticketPrice  numeric  NULL 机票价格
ticketSum  numeric  NULL 结算金额
customerMemo  text  NULL 备注
3 数据库结构的实现
经过前面的需求分析和概念结构设计以后，得到数据库的逻辑结构。现在就可以在SQL Server 2000数据库系统中实现该逻辑结构。这是利用SQL Server 2000数据库系统中的SQL 查询分析器实现的。下面给出创建这些表格的SQL语句。
3.1 创建系统用户表
CREATE TABLE [dbo].[user_Info1] (
 [user_ID] [char] (10) COLLATE Chinese_PRC_CI_AS NOT NULL ,
 [user_PWD] [char] (10) COLLATE Chinese_PRC_CI_AS NULL ,
 [user_Des] [char] (10) COLLATE Chinese_PRC_CI_AS NULL
) ON [PRIMARY]
3.2 创建舱位等级信息表
CREATE TABLE [dbo].[serviceInfo] (
 [serviceNO] [char] (4) COLLATE Chinese_PRC_CI_AS NOT NULL ,
 [serviceName] [nvarchar] (20) COLLATE Chinese_PRC_CI_AS NULL ,
 [noPresent] [char] (2) COLLATE Chinese_PRC_CI_AS NULL ,
 [noNewsPaper] [char] (2) COLLATE Chinese_PRC_CI_AS NULL ,
 [noDrink] [char] (2) COLLATE Chinese_PRC_CI_AS NULL ,
 [noFood] [char] (2) COLLATE Chinese_PRC_CI_AS NULL ,
 [noMovie] [char] (2) COLLATE Chinese_PRC_CI_AS NULL ,
 [canChange] [char] (2) COLLATE Chinese_PRC_CI_AS NULL ,
 [canCancel] [char] (2) COLLATE Chinese_PRC_CI_AS NULL ,
 [canDiscount] [char] (2) COLLATE Chinese_PRC_CI_AS NULL ,
 [serviceMemo] [text] COLLATE Chinese_PRC_CI_AS NULL
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
3.3 创建客机信息表
CREATE TABLE [dbo].[planeInfo] (
 [planeNO] [char] (18) COLLATE Chinese_PRC_CI_AS NOT NULL ,
 [planeType] [char] (20) COLLATE Chinese_PRC_CI_AS NULL ,
 [buyDate] [datetime] NULL ,
 [serveDate] [datetime] NULL ,
 [isCommon] [nvarchar] (20) COLLATE Chinese_PRC_CI_AS NULL ,
 [isCommercial] [nvarchar] (20) COLLATE Chinese_PRC_CI_AS NULL ,
 [isFirst] [nvarchar] (20) COLLATE Chinese_PRC_CI_AS NULL ,
 [planeMemo] [text] COLLATE Chinese_PRC_CI_AS NULL
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
3.4 创建航线信息表
CREATE TABLE [dbo].[airlineInfo] (
 [airlineNO] [char] (14) COLLATE Chinese_PRC_CI_AS NOT NULL ,
 [departCity] [nvarchar] (50) COLLATE Chinese_PRC_CI_AS NULL ,
 [arrivalCity] [nvarchar] (50) COLLATE Chinese_PRC_CI_AS NULL ,
 [departDate] [char] (10) COLLATE Chinese_PRC_CI_AS NULL ,
 [departTime] [char] (10) COLLATE Chinese_PRC_CI_AS NULL ,
 [arrivalTime] [char] (10) COLLATE Chinese_PRC_CI_AS NULL ,
 [planeNO] [char] (18) COLLATE Chinese_PRC_CI_AS NULL ,
 [commonPrice] [numeric](18, 2) NULL ,
 [commercialPrice] [numeric](18, 2) NULL ,
 [firstPrice] [numeric](18, 2) NULL ,
 [airlineMemo] [text] COLLATE Chinese_PRC_CI_AS NULL

) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
3.5 创建客户类型信息表
CREATE TABLE [dbo].[customerType] (
 [ctypeNO] [char] (14) COLLATE Chinese_PRC_CI_AS NOT NULL ,
 [ctypeName] [char] (20) COLLATE Chinese_PRC_CI_AS NULL ,
 [discount] [numeric](2, 0) NULL ,
 [ctypeMemo] [text] COLLATE Chinese_PRC_CI_AS NULL
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
3.6 创建客户信息表
CREATE TABLE [dbo].[customerInfo] (
 [customerNO] [char] (14) COLLATE Chinese_PRC_CI_AS NOT NULL ,
 [customerName] [char] (50) COLLATE Chinese_PRC_CI_AS NULL ,
 [customerSex] [char] (2) COLLATE Chinese_PRC_CI_AS NULL ,
 [customerID] [char] (18) COLLATE Chinese_PRC_CI_AS NULL ,
 [customerTele] [char] (20) COLLATE Chinese_PRC_CI_AS NULL ,
 [customerType] [char] (14) COLLATE Chinese_PRC_CI_AS NULL ,
 [customerMemo] [text] COLLATE Chinese_PRC_CI_AS NULL
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
3.7 创建订票信息表
CREATE TABLE [dbo].[ticketInfo] (
 [ticketNO] [char] (14) COLLATE Chinese_PRC_CI_AS NOT NULL ,
 [customerNO] [char] (14) COLLATE Chinese_PRC_CI_AS NULL ,
 [customerName] [char] (50) COLLATE Chinese_PRC_CI_AS NULL ,
 [customerType] [char] (14) COLLATE Chinese_PRC_CI_AS NULL ,
 [discount] [numeric](18, 0) NULL ,
 [airlineNO] [char] (14) COLLATE Chinese_PRC_CI_AS NULL ,
 [departCity] [nvarchar] (50) COLLATE Chinese_PRC_CI_AS NULL ,
 [arrivalCity] [nvarchar] (50) COLLATE Chinese_PRC_CI_AS NULL ,
 [ticketDate] [datetime] NULL ,
 [serviceType] [nvarchar] (20) COLLATE Chinese_PRC_CI_AS NULL ,
 [ticketPrice] [numeric](18, 2) NULL ,
 [ticketSum] [numeric](18, 2) NULL ,
 [ticketMemo] [text] COLLATE Chinese_PRC_CI_AS NULL
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
4 航空公司管理信息系统主窗体的创建
上面的SQL语句在SQL Server 2000中查询分析器的执行，将自动产生需要的所有表格。有关数据库结构的所有后台工作已经完成。现在将通过航空公司管理信息系统中各个功能模块的实现，讲解如何使用Visual Basic来编写数据库系统的客户端程序。
4.1 创建工程项目——MIS_Ticket
启动Visual Basic后，单击File|New Project菜单，在工程模板中选择Standard EXE，Visual Basic将自动产生一个Form窗体，属性都是缺省设置。这里我们删除这个窗体，单击File|Save Project菜单，将这个工程项目命名为MIS_Ticket。
4.2 创建航空公司管理信息系统的主窗体
这个项目我们使用多论文界面，单击工具栏中的ADD MDI Form按钮，产生一个窗体。在这个窗体上添加所需的控件，窗体和控件的属性设置见表9-7。创建好的窗体如图9-10所示。
表9-7                      主窗体及其控件属性设置
控  件 属  性 属性取值
frmMain(Form) Name FrmMain
 Caption 大唐航空公司信息管理系统
 StartUpPositon CenterScreen
 WindowState Maximized
SbStatusBar(StatusBar) Name SbStatusBar
 Panels(1) Style SbrText
 Panels(2) Style SbrDate
 Panels(3) Style SbrTime

图9-10 航空公司管理信息系统主窗体

在主窗体中加入状态栏控件，可以实时反映系统中的各个状态的变化。状态栏控件需要在通常的属性窗口中设置一般属性，还需要在其特有的弹出式菜单中进行设置。选中状态栏控件，单击鼠标右键，选中Property菜单，然后设置属性。面板1用来显示各种文本信息，面板2用来显示当前日期，面板3用来显示当前时间。
4.3 创建主窗体的菜单
在如图9-10所示的主窗体中，单击鼠标右键，选择弹出式菜单中的Menu Editor，创建如图9-11所示的菜单结构：

图9-11 主窗体中的菜单结构
4.4 创建公用模块
在Visual Basic中可以用公用模块来存放整个工程项目公用的函数、过程和全局变量等。这样可以极大地提高代码的效率。在项目资源管理器中为项目添加一个Module，保存为Module1.bas。下面就可以开始添加需要的代码了。
由于系统中各个功能模块都将频繁使用数据库中的各种数据，因此需要一个公共的数据操作函数，用以执行各种SQL语句。添加函数ExecuteSQL，代码如下：
Public Function ExecuteSQL(ByVal SQL _
   As String, MsgString As String) _
   As ADODB.Recordset
'执行SQL语句，并返回记录集对象
   ‘声明一个连接
   Dim cnn As ADODB.Connection
   ‘声明一个数据集对象
   Dim rst As ADODB.Recordset
   Dim sTokens() As String
'异常处理
   On Error GoTo ExecuteSQL_Error
'用Split函数产生一个包含各个子串的数组  
   sTokens = Split(SQL)
  ‘创建一个连接
   Set cnn = New ADODB.Connection
'打开连接
   cnn.Open ConnectString
   If InStr("INSERT,DELETE,UPDATE", _
      UCase$(sTokens(0))) Then
     ‘执行查询语句
      cnn.Execute SQL
      MsgString = sTokens(0) & _
         " query successful"
   Else
      Set rst = New ADODB.Recordset
      rst.Open Trim$(SQL), cnn, _
         adOpenKeyset, _
         adLockOptimistic
      'rst.MoveLast     'get RecordCount
'返回记录集对象
      Set ExecuteSQL = rst
      MsgString = "查询到" & rst.RecordCount & _
         " 条记录 "
   End If
ExecuteSQL_Exit:
   Set rst = Nothing
   Set cnn = Nothing
   Exit Function  
ExecuteSQL_Error:
   MsgString = "查询错误: " & _
      Err.Description
   Resume ExecuteSQL_Exit
End Function
 
在ExecuteSQL函数中使用了Connect String函数，这个函数用来连接数据库，代码如下：
Public Function ConnectString() _
   As String
'返回一个数据库连接
   ConnectString = "FileDSN=ticket.dsn;UID=sa;PWD="
End Function
在录入有关信息时，需要回车来进入下一个文本框，这样对软件使用者非常方便。在所有的功能模块都需要这个函数，所以将它放在公用模块中，代码如下：
Public Sub EnterToTab(Keyasc As Integer)
    '判断是否为回车键

    If Keyasc = 13 Then
        '转换成Tab键
        SendKeys "{TAB}"
    End If
End Sub
Keyasc用来保存当前按键，SendKeys函数用来指定的按键。一旦按下回车键，将返回Tab键，下一个控件自动获得输入焦点。
添加全局变量，用来记录各个功能模块的读写状态，代码如下：
Public gintSmode As Integer '记载舱位等级功能模块的读写状态
Public gintPmode As Integer '记载客机信息模块的读写状态
Public gintAmode As Integer '记载航线信息模块的读写状态
Public gintTmode As Integer '记载客户类型模块的读写状态
Public gintCmode As Integer '记载客户信息模块的读写状态
Public gintKmode As Integer '记载订票信息模块的读写状态
这些全局变量用来记录是添加状态还是修改状态，赋值1为添加，赋值2为修改。
由于航空公司管理信息管理系统启动后，需要对用户进行判断。如果登录者是授权用户，将进入系统，否则将停止程序的执行。这个判断需要在系统运行的最初进行，因此将代码放在公用模块中。
5 系统用户管理模块的创建
用户管理模块主要实现：
用户登录。
添加用户。
修改用户密码。
 
6 舱位信息管理模块的创建
舱位信息管理模块主要实现如下功能：
添加舱位信息。
修改舱位信息。
删除舱位信息。
6.1 显示舱位信息窗体的创建
选择“航线信息管理|舱位信息”菜单，将出现如图9-12所示的窗体。

图9-12 舱位等级信息窗体
这个窗体用来显示舱位等级信息，并且可以对各条记录进行操作。在载入窗体时，程序将自动载入所有记录，代码如下：
Private Sub menuCarbin_Click()
    frmService.txtSQL = "select * from serviceInfo"
    frmService.Show 0
End Sub
窗体的Show方法后面加上0或者1，可以得到不同的窗体显示方式。参数为0时，显示的窗体为无模式形式，窗体切换时不需要进行其他操作；参数为1时，显示的窗体为有模式形式，窗体切换时必须进行相关操作。
载入窗体时将自动显示各条记录，代码如下：
Private Sub Form_Load()
    ShowTitle
    ShowData
End Sub
函数ShowTitle用来显示表头，代码如下：
Private Sub ShowTitle()
    Dim i As Integer
    With msgList
        .Cols = 12
        .TextMatrix(0, 1) = "等级编号"
        .TextMatrix(0, 2) = "机舱等级"
        .TextMatrix(0, 3) = "是否有礼品"
        .TextMatrix(0, 4) = "是否有报纸"
        .TextMatrix(0, 5) = "是否有饮料"
        .TextMatrix(0, 6) = "是否有午餐"
        .TextMatrix(0, 7) = "是否提供电影"
        .TextMatrix(0, 8) = "是否可以改签"
        .TextMatrix(0, 9) = "是否可以退票"
        .TextMatrix(0, 10) = "是否可以打折"
        .TextMatrix(0, 11) = "备注信息"
        '固定表头
        .FixedRows = 1
        '设置各列的对齐方式
        For i = 0 To 11
            .ColAlignment(i) = 0
        Next i
        '表头项居中
        .FillStyle = flexFillRepeat
        .Col = 0
        .Row = 0
        .RowSel = 1
        .ColSel = .Cols - 1
        .CellAlignment = 4
        '设置单元大小
        .ColWidth(0) = 1000
        .ColWidth(1) = 1000
        .ColWidth(2) = 2000
        .ColWidth(3) = 1000
        .ColWidth(4) = 1000
        .ColWidth(5) = 1000
        .ColWidth(6) = 1000
        .ColWidth(7) = 1000
        .ColWidth(8) = 1000
        .ColWidth(9) = 1000
        .ColWidth(10) = 1000
        .ColWidth(11) = 1000
        .Row = 1
    End With
End Sub
函数ShowData把各条记录加到表格中，并显示出来，代码如下：
Private Sub ShowData()
    Dim j As Integer

    Dim i As Integer
    Dim MsgText As String
‘获得数据集
    Set mrc = ExecuteSQL(txtSQL, MsgText)
        With msgList
        .Rows = 1
        ‘判断是否为空
        Do While Not mrc.EOF
            ‘移动到下一行
            .Rows = .Rows + 1
            ‘循环
            For i = 1 To mrc.Fields.Count
                ‘判断是否为空
                If Not IsNull(Trim(mrc.Fields(i - 1))) Then
                ‘根据数据类型显示
                Select Case mrc.Fields(i - 1).Type
                    Case adDBDate
                        .TextMatrix(.Rows - 1, i) = Format(mrc.Fields(i - 1) & "", "yyyy-mm-dd")
                    Case Else
                        .TextMatrix(.Rows - 1, i) = mrc.Fields(i - 1) & ""
                End Select
                End If
            Next I
            ‘移动到下一条记录
            mrc.MoveNext
        Loop
    End With
    ‘关闭数据集对象
    mrc.Close
End Sub
在窗体显示时，可以控制窗体中各个控件按照要求的位置显示。可以在窗体的Resize事件中加入代码，代码如下：
Private Sub Form_Resize()
     ‘判断当前窗体所处的状态，当前窗体不处于最小化状态并且主窗体不处于最小化状态时进行后面的操作
    If Me.WindowState <> vbMinimized And fMainForm.WindowState <> vbMinimized Then
        '边界处理
        If Me.ScaleHeight < 10 * lblTitle.Height Then
            Exit Sub

        End If
        If Me.ScaleWidth < lblTitle.Width + lblTitle.Width / 2 Then
            Exit Sub
        End If
        '控制控件的位置
        lblTitle.Top = lblTitle.Height
        lblTitle.Left = (Me.Width - lblTitle.Width) / 2
        ‘控制表格控件的位置
        msgList.Top = lblTitle.Top + lblTitle.Height + lblTitle.Height / 2
        msgList.Width = Me.ScaleWidth - 200
        msgList.Left = Me.ScaleLeft + 100
        msgList.Height = Me.ScaleHeight - msgList.Top - 1500
        ‘控制按钮位置
        Frame2.Top = msgList.Top + msgList.Height + 50
        Frame2.Left = Me.ScaleWidth / 2 - 3000
    End If
End Sub
6.2 添加舱位信息窗体的创建
在舱位信息显示窗体中单击“添加”按钮，将出现如图9-13所示的窗体。

图9-13 添加舱位等级信息窗体
载入窗体时，首先根据标志变量判断状态，然后决定是添加还是修改，代码如下：
Private Sub Form_Load()
    Dim intCount As Integer
    Dim MsgText As String
    Dim i As Integer
    ‘判断是否为添加
    If gintSmode = 1 Then
        Me.Caption = Me.Caption & "添加"
        For i = 0 To 7
            Combo1(i).AddItem "否"
            Combo1(i).AddItem "是"
            Combo1(i).ListIndex = 0
        Next I
    ‘载入当前选择记录内容
    ElseIf gintSmode = 2 Then
        Set mrc = ExecuteSQL(txtSQL, MsgText)
        ‘判断记录是否为空
        If mrc.EOF = False Then
            With mrc
                For intCount = 0 To 1
                    txtItem(intCount) = .Fields(intCount)
                Next intCount
                txtItem(2) = .Fields(10)
                For i = 0 To 7
                    Combo1(i).AddItem "否"
                    Combo1(i).AddItem "是"
                    Combo1(i).ListIndex = 0
                Next i
            End With
            txtItem(0).Enabled = False
        End If
        Me.Caption = Me.Caption & "修改"
    End If
    mblChange = False
End Sub
输入内容完毕，单击“保存”按钮，将首先判断输入内容是否满足要求，然后添加到数据库中。代码如下：
Private Sub cmdSave_Click()
    Dim intCount As Integer
    Dim sMeg As String
    Dim MsgText As String
    ‘判断输入内容是否为空
    For intCount = 0 To 1
        If Trim(txtItem(intCount) & " ") = "" Then
            Select Case intCount
                Case 0
                    sMeg = "机舱等级编号"
                Case 1
                    sMeg = "机舱等级名称"
            End Select
            sMeg = sMeg & "不能为空！"
            MsgBox sMeg, vbOKOnly + vbExclamation, "警告"
            txtItem(intCount).SetFocus
            Exit Sub
        End If
    Next intCount
    ‘判断输入内容是否为数字
    If Not IsNumeric(Trim(txtItem(0))) Then
        sMeg = "机舱等级编号"
        sMeg = sMeg & "请输入数字！"
        MsgBox sMeg, vbOKOnly + vbExclamation, "警告"
        txtItem(0).SetFocus
    End If
    '添加判断是否有相同的ID记录
    If gintSmode = 1 Then
        txtSQL = "select * from serviceInfo where serviceNO='" & Trim(txtItem(0)) & "'"
        Set mrc = ExecuteSQL(txtSQL, MsgText)
        If mrc.EOF = False Then
            MsgBox "已经存在此编号的记录！", vbOKOnly + vbExclamation, "警告"
            txtItem(0).SetFocus
            Exit Sub
        End If
        mrc.Close
    End If
    '判断是否有相同内容的记录
    txtSQL = "select * from serviceInfo where serviceNO<>'" & Trim(txtItem(0)) & "' and serviceName='" & Trim(txtItem(1)) & "'"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    If mrc.EOF = False Then
        MsgBox "已经存在相同机舱等级的记录！", vbOKOnly + vbExclamation, "警告"
        txtItem(1).SetFocus
        Exit Sub
    End If
    '先删除已有记录
    txtSQL = "delete from serviceInfo where serviceNO='" & Trim(txtItem(0)) & "'"

    Set mrc = ExecuteSQL(txtSQL, MsgText)
    '再加入新记录
    txtSQL = "select * from serviceInfo"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    mrc.AddNew
    For intCount = 0 To 1
        mrc.Fields(intCount) = Trim(txtItem(intCount))
    Next intCount
    For intCount = 0 To 7
        mrc.Fields(intCount + 2) = Trim(Combo1(intCount))
    Next intCount
    mrc.Fields(10) = Trim(txtItem(2))
    ‘更新数据集内容
    mrc.Update
    ‘关闭数据集内容
    mrc.Close
    If gintSmode = 1 Then
        MsgBox "添加记录成功！", vbOKOnly + vbExclamation, "添加记录"
        For intCount = 0 To 1
            txtItem(intCount) = ""
        Next intCount
        For intCount = 0 To 3
            Combo1(intCount).ListIndex = 0
        Next intCount
        txtItem(2) = ""
        mblChange = False
        Unload frmService
        frmService.txtSQL = "select * from serviceInfo"
        frmService.Show
    ElseIf gintSmode = 2 Then
        Unload Me
        Unload frmService
        frmService.txtSQL = "select * from serviceInfo"
        frmService.Show
    End If
End Sub
6.3 修改舱位等级信息
在舱位等级信息列表中选择需要修改的记录，然后单击“修改”按钮，将出现如图9-13所示的窗体。选择记录的内容将显示在窗体中，可以进行修改，最后保存修改后的记录。代码如下：
Private Sub cmdModify_Click()
    Dim intCount As Integer
    判断列表中是否有记录
    If frmService.msgList.Rows > 1 Then
        ‘改变状态变量
        gintSmode = 2
        ‘记录选择记录位置
        intCount = msgList.Row
        If intCount > 0 Then
           frmService1.txtSQL = "select * from serviceInfo where serviceNO ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
           frmService1.Show 1
        Else
            MsgBox "警告", vbOKOnly + vbExclamation, "请首先选择需要修改的记录！"
        End If
    End If
End Sub
6.4 删除舱位等级信息
在舱位等级信息列表中选择需要删除的记录，然后单击“删除”按钮，将删除当前记录，代码如下：
Private Sub cmdDelete_Click()
    Dim txtSQL As String
    Dim intCount As Integer
    Dim mrc As ADODB.Recordset
    Dim MsgText As String
    ‘判断信息列表中内容是否为空
    If msgList.Rows > 1 Then
       ‘提示信息
        If MsgBox("真的要删除机舱等级为" & Trim(msgList.TextMatrix(msgList.Row, 2)) & "的记录吗？", vbOKCancel + vbExclamation, "警告") = vbOK Then
            ‘记录选择记录位置
            intCount = msgList.Row
           ‘删除重复记录
            txtSQL = "delete from serviceInfo where serviceNO ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
            Set mrc = ExecuteSQL(txtSQL, MsgText)
           ‘卸载窗体
            Unload frmService
            ‘重新载入记录并显示
            frmService.txtSQL = "select * from serviceInfo"
            frmService.Show
        End If
    End If
End Sub
7 客机信息管理模块的创建
客机信息管理模块主要实现如下功能：
添加客机信息。
修改客机信息。
删除客机信息。
查询客机信息。
7.1 显示客机信息窗体的创建
选择“航线信息管理|客机信息”菜单，将出现如图9-14所示的窗体。所有客机信息都将显示出来。窗体的Load事件调用ShowTitle、ShowData函数，将所有记录显示出来。

图9-14 显示客机信息列表窗体
7.2 添加客机信息窗体的创建
单击客机信息列表中的“添加”按钮，将出现如图9-15所示的窗体。

图9-15 添加客机信息列表
输入内容完毕，单击“保存”按钮，将首先判断输入内容是否满足要求，然后将记录添加到数据库中，代码如下：
Private Sub cmdSave_Click()
    Dim intCount As Integer
    Dim sMeg As String
    Dim MsgText As String
    ‘判断输入内容是否为空
    For intCount = 0 To 6
        If Trim(txtItem(intCount) & " ") = "" Then
            Select Case intCount
                Case 0
                    sMeg = "客机编号"
                Case 1
                    sMeg = "客机型号"
                Case 2
                    sMeg = "购买时间"
                Case 3
                    sMeg = "服役时间"
                Case 4
                    sMeg = "经济舱座位数量"
                Case 5
                    sMeg = "公务舱座位数量"
                Case 6
                    sMeg = "头等舱座位数量"
            End Select
            sMeg = sMeg & "不能为空！"
            MsgBox sMeg, vbOKOnly + vbExclamation, "警告"
            txtItem(intCount).SetFocus
            Exit Sub
        End If
    Next intCount
    ‘判断输入内容为数字
    For intCount = 4 To 6
        If Not IsNumeric(Trim(txtItem(intCount))) Then
            sMeg = "座位数量"
            sMeg = sMeg & "请输入数字！"
            MsgBox sMeg, vbOKOnly + vbExclamation, "警告"
            txtItem(intCount).SetFocus
        End If
    Next intCount
    ‘判断输入内容是否为日期
    For intCount = 2 To 3
        If IsDate(txtItem(intCount)) Then
            txtItem(intCount) = Format(txtItem(intCount), "yyyy-mm-dd")
        Else
            MsgBox "时间应输入日期（yyyy-mm-dd）！", vbOKOnly + vbExclamation, "警告"
            txtItem(intCount).SetFocus
            Exit Sub
        End If
    Next intCount
    '添加判断是否有相同的ID记录
    If gintPmode = 1 Then
        txtSQL = "select * from planeInfo where planeNO='" & Trim(txtItem(0)) & "'"
        Set mrc = ExecuteSQL(txtSQL, MsgText)
        If mrc.EOF = False Then
            MsgBox "已经存在此编号的记录！", vbOKOnly + vbExclamation, "警告"
            txtItem(0).SetFocus
            Exit Sub
        End If
        mrc.Close
    End If
    '先删除已有记录
    txtSQL = "delete from planeInfo where planeNO='" & Trim(txtItem(0)) & "'"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    '再加入新记录
    txtSQL = "select * from planeInfo"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    mrc.AddNew
    For intCount = 0 To 7
        mrc.Fields(intCount) = Trim(txtItem(intCount))
    Next intCount
    ‘更新数据集
    mrc.Update
    ‘关闭数据集对象
    mrc.Close
    If gintPmode = 1 Then
        MsgBox "添加记录成功！", vbOKOnly + vbExclamation, "添加记录"
        For intCount = 0 To 7
            txtItem(intCount) = ""
        Next intCount
        mblChange = False
        Unload frmPlane
        frmPlane.txtSQL = "select * from planeInfo"
        frmPlane.Show
    ElseIf gintPmode = 2 Then
        Unload Me
        Unload frmPlane
        frmPlane.txtSQL = "select * from planeInfo"
        frmPlane.Show
    End If
End Sub
7.3 修改客机信息
在客机信息列表中选择记录，然后单击“修改”按钮。当前记录将显示在如图9-15所示的窗体中，可以进行修改。代码如下：
Private Sub cmdModify_Click()
    Dim intCount As Integer
    ‘判断列表内容是否为空
    If frmPlane.msgList.Rows > 1 Then
        gintPmode = 2
        ‘记载选择记录的位置
        intCount = msgList.Row
        If intCount > 0 Then
           frmPlane1.txtSQL = "select * from planeInfo where planeNO ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
           frmPlane1.Show 1
        Else
            MsgBox "警告", vbOKOnly + vbExclamation, "请首先选择需要修改的记录！"
        End If
    End If
End Sub
7.4 删除客机信息
在客机信息列表中选择记录，然后单击“删除”按钮，当前记录将被删除。代码如下：
Private Sub cmdDelete_Click()
    Dim txtSQL As String
    Dim intCount As Integer
    Dim mrc As ADODB.Recordset
    Dim MsgText As String
    ‘判断列表内容是否为空
    If msgList.Rows > 1 Then
        If MsgBox("真的要删除客机编号为" & Trim(msgList.TextMatrix(msgList.Row, 1)) & "的型号为" & Trim(msgList.TextMatrix(msgList.Row, 2)) & "的客机记录吗？", vbOKCancel + vbExclamation, "警告") = vbOK Then
        ‘记载选择记录的位置
            intCount = msgList.Row
            txtSQL = "delete from planeInfo where planeNO ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
            Set mrc = ExecuteSQL(txtSQL, MsgText)
            Unload frmPlane
            ‘重新载入所有记录，并显示出来
            frmPlane.txtSQL = "select * from planeInfo"
            frmPlane.Show
        End If
    End If
End Sub
7.5 查询客机信息
在客机信息列表中单击“查询”按钮，将出现如图9-16所示的窗体。

图9-16 查询客机信息的窗体
载入窗体时，将自动加入所有客机编号和客机型号的信息，代码如下：
Private Sub Form_Load()
    Dim i As Integer
    Dim sSql As String
    Dim txtSQL As String
    Dim MsgText As String
    Dim mrc As ADODB.Recordset
    ‘清楚各个列表框中的内容
    For i = 0 To 1
        Combo1(i).Clear
    Next i
    ‘选择数据库中所有客机编号的内容
    txtSQL = "select DISTINCT planeNO from planeInfo"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    ‘判断数据库是否为空
    If Not mrc.EOF Then
        Do While Not mrc.EOF
            Combo1(0).AddItem Trim(mrc.Fields(0))
            mrc.MoveNext
        Loop
    Else
        MsgBox "请先进行客机信息设置！", vbOKOnly + vbExclamation, "警告"
        Exit Sub
    End If
    mrc.Close
    ‘选择所有数据库中有关飞机型号的内容
    txtSQL = "select DISTINCT planeType from planeInfo"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    ‘判断数据集对象是否为空
    If Not mrc.EOF Then
        Do While Not mrc.EOF
            Combo1(1).AddItem Trim(mrc.Fields(0))
            mrc.MoveNext
        Loop
    Else
        MsgBox "请先进行客机信息设置！", vbOKOnly + vbExclamation, "警告"
        Exit Sub
    End If
    ‘关闭数据集对象
    mrc.Close
End Sub
设置完查询内容和方式后，单击cmdOK按钮将进行查询。所有满足条件的记录将显示在如图9-14所示的窗体中，代码如下：
Private Sub cmdOK_Click()
    Dim sQSql As String
    ‘判断是否按照客机编号查询
    If chkItem(0).Value = vbChecked Then
        sQSql = " planeNO = '" & Trim(Combo1(0) & " ") & "'"
    End If
    ‘判断是否按照客机型号查询
    If chkItem(1).Value = vbChecked Then
        If Trim(sQSql & " ") = "" Then
            sQSql = " planeType ='" & Trim(Combo1(1) & " ") & "'"
        Else
            sQSql = sQSql & " and planeType ='" & Trim(Combo1(1) & " ") & "'"
        End If
    End If
    ‘判断查询内容是否为空
    If Trim(sQSql) = "" Then
        MsgBox "请设置查询条件！", vbOKOnly + vbExclamation, "警告"
        Me.Hide
        Exit Sub
    Else
        ‘显示所有满足查询条件的内容
        frmPlane.txtSQL = "select * from planeInfo where" & sQSql
        Me.Hide
        Unload frmPlane
        frmPlane.Show
    End If
End Sub
8 航线信息管理模块的创建
航线信息管理模块主要实现如下功能：
添加航线信息。
修改航线信息。
删除航线信息。
查询航线信息。
8.1 显示航线信息窗体的创建
选择“航线信息管理|航线信息”菜单，将出现如图9-17所示的窗体。所有航线信息都将显示出来。窗体的Load事件调用ShowTitle、ShowData函数，将所有记录显示出来。

图9-17 显示客机信息窗体
8.2 添加航线信息窗体的创建
选择“航线信息管理|航线信息”菜单，将出现如图9-18所示的窗体，用来添加航线信息。

图9-18 添加航线窗体
输入完航线信息后，单击“保存”按钮：程序首先检查输入内容是否符合要求，然后检查是否有重复记录，最后添加到数据库中。
8.3 修改航线信息
在航线信息列表中选择记录，然后单击“修改”按钮。当前记录将显示在如图9-18所示的窗体中，可以进行修改。代码如下：
Private Sub cmdModify_Click()
    Dim intCount As Integer
    ‘判断列表内容是否为空
    If frmAirline.msgList.Rows > 1 Then
        gintAmode = 2
        ‘记载选择记录的位置
        intCount = msgList.Row
        If intCount > 0 Then
           frmAirline1.txtSQL = "select * from airlineInfo where airlineNO ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
           frmAirline1.Show 1
        Else
            MsgBox "警告", vbOKOnly + vbExclamation, "请首先选择需要修改的记录！"
        End If
    End If
End Sub
8.4 删除航线信息
在航线信息列表中选择记录，然后单击“删除”按钮，当前记录将被删除。代码如下：
Private Sub cmdDelete_Click()
    Dim txtSQL As String
    Dim intCount As Integer
    Dim mrc As ADODB.Recordset
    Dim MsgText As String
    ‘判断列表内容是否为空
    If msgList.Rows > 1 Then
        If MsgBox("真的要删除" & Trim(msgList.TextMatrix(msgList.Row, 4)) & "从" & Trim(msgList.TextMatrix(msgList.Row, 2)) & "出发到" & Trim(msgList.TextMatrix(msgList.Row, 3)) & "的航线记录吗？", vbOKCancel + vbExclamation, "警告") = vbOK Then
            ‘记载选择记录位置
            intCount = msgList.Row
            txtSQL = "delete from airlineInfo where airlineNO ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
            Set mrc = ExecuteSQL(txtSQL, MsgText)
           ‘重新载入记录并显示
            Unload frmAirline
            frmAirline.txtSQL = "select * from airlineInfo"
            frmAirline.Show
        End If
    End If
End Sub
8.5 查询航线信息
在航线信息列表中单击“查询”按钮，将出现如图9-19所示的窗体。

图9-19 航线信息查询窗体
载入窗体时自动加入出发城市和到达城市的内容，代码如下：
Private Sub Form_Load()
    Dim i As Integer
    Dim sSql As String
    Dim txtSQL As String
    Dim MsgText As String
    Dim mrc As ADODB.Recordset
    ‘清除列表框中的内容
    For i = 0 To 1
        Combo1(i).Clear
    Next i
    ‘选择数据库中与出发城市有关的内容
    txtSQL = "select DISTINCT departCity from airlineInfo"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    ‘判断数据集是否为空
    If Not mrc.EOF Then
        Do While Not mrc.EOF
            Combo1(0).AddItem Trim(mrc.Fields(0))
            mrc.MoveNext
        Loop
    Else
        MsgBox "请先进行航线信息设置！", vbOKOnly + vbExclamation, "警告"
        Exit Sub
    End If
    mrc.Close
    txtSQL = "select DISTINCT arrivalCity from airlineInfo"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    If Not mrc.EOF Then
        Do While Not mrc.EOF
            Combo1(1).AddItem Trim(mrc.Fields(0))
            mrc.MoveNext
        Loop
    Else
        MsgBox "请先进行航线信息设置！", vbOKOnly + vbExclamation, "警告"
        Exit Sub
    End If
    mrc.Close
End Sub
设置查询内容后，单击“确定”按钮，所有满足查询条件的内容显示在航线信息列表中。
9 客户类型信息管理模块的创建
客户类型信息管理模块主要实现如下功能：
添加客户类型信息。
修改客户类型信息。
删除客户类型信息。
9.1 显示客户类型信息窗体的创建
选择“客户信息管理|客户类型”菜单，将出现如图9-20所示的窗体。所有客户类型信息都将显示出来。窗体的Load事件调用ShowTitle、ShowData函数，将所有记录显示出来。

图9-20 显示客户类型信息窗体
9.2 添加客户类型信息窗体的创建
在客户类型信息列表中单击“添加”按钮，将出现如图9-21所示的窗体，用来添加客户类型信息。

图9-21 添加客户类型信息窗体
输入内容完毕，单击“保存”按钮，程序将首先检查内容是否符合要求，然后检查是否有重复记录，最后添加到数据库中。
9.3 修改客户类型信息
在客户类型信息列表中选择需要修改的记录，然后单击“修改”按钮，当前记录将出现在如图9-14所示的窗体中。修改完毕，单击“保存”按钮，修改后的记录保存到数据库中。代码如下：
Private Sub cmdModify_Click()
    Dim intCount As Integer
    ‘判断列表内容是否为空
    If frmcType.msgList.Rows > 1 Then
        gintTmode = 2
        ‘记载选择记录的位置
        intCount = msgList.Row
       ‘判断是否选择记录
        If intCount > 0 Then
         ‘显示需要修改的记录
           frmcType1.txtSQL = "select * from customerType where ctypeNO ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
           frmcType1.Show 1
        Else
            MsgBox "警告", vbOKOnly + vbExclamation, "请首先选择需要修改的记录！"
        End If
    End If
End Sub
9.4 删除客户类型信息
选择客户类型信息列表中需要删除的记录，然后单击“删除”按钮，可以删除所选记录。代码如下：
Private Sub cmdDelete_Click()
    Dim txtSQL As String
    Dim intCount As Integer
    Dim mrc As ADODB.Recordset
    Dim MsgText As String
    ‘判断列表内容是否为空
    If msgList.Rows > 1 Then
        ‘提示信息
        If MsgBox("真的要删除客户种类为" & Trim(msgList.TextMatrix(msgList.Row, 2)) & "的记录吗？", vbOKCancel + vbExclamation, "警告") = vbOK Then
        ‘记载选择记录的位置
            intCount = msgList.Row
           ‘删除记录
            txtSQL = "delete from customerType where ctypeNO ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
            Set mrc = ExecuteSQL(txtSQL, MsgText)
           ‘卸载窗体
            Unload frmcType
           ‘选择所有记录
            frmcType.txtSQL = "select * from customerType"
           ‘显示窗体
            frmcType.Show
        End If
    End If
End Sub
10 客户信息管理模块的创建
客户信息管理模块主要实现如下功能：
添加客户信息。
修改客户信息。
删除客户信息。
查询客户信息。
10.1 显示客户信息窗体的创建
选择“客户信息管理|客户信息”菜单，将首先出现如图9-22所示的窗体。所有客户类型信息都将显示出来。窗体的Load事件调用ShowTitle、ShowData函数，将所有记录显示出来。

图9-22 显示客户信息窗体
10.2 添加客户信息窗体的创建
在客户信息列表中单击“添加”按钮，将出现如图9-23所示的窗体，用来添加客户信息。

图9-23 添加客户信息窗体
输入内容完毕，单击“保存”按钮，程序将首先检查内容是否符合要求，然后检查是否有重复记录，最后添加到数据库中。
10.3 修改客户信息
在客户信息列表中选择需要修改的记录，然后单击“修改”按钮，当前记录将出现在如图9-23所示的窗体中。修改完毕，单击“保存”按钮，修改后的记录保存到数据库中。代码如下：
Private Sub cmdModify_Click()
    Dim intCount As Integer
   ‘判断列表内容是否为空
    If frmCustomer.msgList.Rows > 1 Then
        gintCmode = 2
        ‘记载选择记录的位置
        intCount = msgList.Row
        ‘判断是否选择记录
        If intCount > 0 Then
           ‘选择点击记录
           frmCustomer1.txtSQL = "select * from customerInfo where customerNO ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
          ‘显示
           frmCustomer1.Show 1
        Else
           ‘提示信息
            MsgBox "警告", vbOKOnly + vbExclamation, "请首先选择需要修改的记录！"
        End If
    End If
End Sub
10.4 删除客户信息
选择客户信息列表中需要删除的记录，然后单击“删除”按钮，可以删除所选记录。代码如下：
Private Sub cmdDelete_Click()
    Dim txtSQL As String
    Dim intCount As Integer
    Dim mrc As ADODB.Recordset
    Dim MsgText As String
   ‘判断列表内容是否为空
    If msgList.Rows > 1 Then
        If MsgBox("真的要删除客户姓名为" & Trim(msgList.TextMatrix(msgList.Row, 2)) & "的客户记录吗？", vbOKCancel + vbExclamation, "警告") = vbOK Then
        ‘记载选择记录的位置
            intCount = msgList.Row
           ‘删除当前记录
            txtSQL = "delete from customerInfo where customerNO ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
           ‘执行查询语句
            Set mrc = ExecuteSQL(txtSQL, MsgText)
            ‘卸载客户信息列表
            Unload frmCustomer
            ‘选择所有记录
            frmCustomer.txtSQL = "select * from customerInfo"
            ‘显示
            frmCustomer.Show
        End If
    End If
End Sub
10.5 查询客户信息
在如图9-22所示的客户信息列表中，单击“查询”按钮，出现如图9-24所示的对话框。

图9-24 客户信息查询窗体
客户信息查询窗体在载入时所有客户信息自动加入到查询内容中。选择合适的查询方式，满足查询条件的记录显示在如图9-22所示的客户信息列表中。
11 订票信息管理模块的创建
订票信息管理模块主要实现如下功能：
添加订票信息。
修改订票信息。
删除订票信息。
查询剩余机票信息。
11.1 显示订票信息窗体的创建
选择“票务信息管理|订票信息”菜单，将首先出现如图9-25所示的窗体。所有订票类型信息都将显示出来。窗体的Load事件调用ShowTitle、ShowData函数，将所有记录显示出来。

图9-25 显示机票信息的窗体
11.2 添加订票信息窗体的创建
在机票信息列表中单击“添加”按钮，将出现如图9-26所示的窗体，用来添加订票信息。

图9-26 添加订票信息的窗体
机票信息包括两部分：航线信息和客户信息。选择出发城市和到达城市，将得到相应的航线信息；选择客户姓名得到相应的客户信息。窗体载入时要求在列表框中加入所有有关航线和客户的信息，代码如下：
Private Sub Form_Load()
    Dim intCount As Integer
    Dim MsgText As String
    Dim i As Integer
    Dim mrcc As ADODB.Recordset
    ‘判断所处状态，添加或者修改
    If gintKmode = 1 Then
        Me.Caption = Me.Caption & "添加"
        ‘产生随机的订票编号
        txtticket = GetRkno()
    ElseIf gintKmode = 2 Then
        Set mrc = ExecuteSQL(txtSQL, MsgText)
        ‘判断数据集对象是否为空
        If mrc.EOF = False Then
            With mrc
                txtticket = .Fields(0)
                txtItem(0) = .Fields(7)
                txtItem(1) = .Fields(12)
            End With
        End If
        Me.Caption = Me.Caption & "修改"
    End If
    ‘清楚列表框中内容
        For i = 0 To 6
            Combo1(i).Clear
        Next i
        ‘选择数据库中所有与出发城市有关的信息
        txtSQL = "select distinct departCity from airlineInfo "
        Set mrcc = ExecuteSQL(txtSQL, MsgText)
        ‘判断数据集对象是否为空
        If Not mrcc.EOF Then
            Do While Not mrcc.EOF
                Combo1(0).AddItem mrcc.Fields(0)
                mrcc.MoveNext
            Loop
        End If
        ‘关闭数据集对象
        mrcc.Close
        ‘选择数据库中所有与到达城市有关的信息
        txtSQL = "select distinct arrivalCity from airlineInfo"

        Set mrcc = ExecuteSQL(txtSQL, MsgText)
        ‘判断数据集对象是否为空
        If Not mrcc.EOF Then
            Do While Not mrcc.EOF
                Combo1(1).AddItem mrcc.Fields(0)
                mrcc.MoveNext
            Loop
        End If
        ‘关闭数据集对象
        mrcc.Close
        ‘选择数据库中所有与舱位等级有关的信息
        txtSQL = "select distinct serviceName from serviceInfo"
        Set mrcc = ExecuteSQL(txtSQL, MsgText)
        ‘判断数据集对象是否为空
        If Not mrcc.EOF Then
            Do While Not mrcc.EOF
                Combo1(2).AddItem mrcc.Fields(0)
                mrcc.MoveNext
            Loop
        End If
        ‘关闭数据集对象
        mrcc.Close
        ‘选择数据库中所有与客户姓名有关的信息
        txtSQL = "select distinct customerName from customerInfo"
        Set mrcc = ExecuteSQL(txtSQL, MsgText)
        ‘判断数据集对象是否为空
        If Not mrcc.EOF Then
            Do While Not mrcc.EOF
                Combo1(4).AddItem mrcc.Fields(0)
                mrcc.MoveNext
            Loop
        End If
        ‘关闭数据集对象
        mrcc.Close
    mblChange = False
End Sub
选择出发城市和到达城市，然后选择舱位类型，将自动显示票价，并用不可见文本框（txtairline、txtairline等）记载航线编号、客户编号等信息。实现代码加在列表框的Click事件中，如下：

Private Sub Combo1_Click(Index As Integer)
    Dim mrcc As ADODB.Recordset
    Dim mrcd As ADODB.Recordset
    Dim MsgText As String
    ‘判断列表框编号
    If Index = 2 Then
        ‘判断出发城市和到达城市是否选择
        If Not (Trim(Combo1(0)) = "" Or Trim(Combo1(1)) = "") Then
            txtSQL = "select *  from airlineInfo where departCity = '" & Trim(Combo1(0)) & "' and arrivalCity = '" & Trim(Combo1(1)) & "'"
            Set mrcc = ExecuteSQL(txtSQL, MsgText)
            ‘判断数据集对象是否为空
            If Not mrcc.EOF Then
                txtairline = mrcc.Fields(0)
                ticketCsum = mrcc!planeNO
                If Trim(Combo1(2)) = "经济舱" Then
                    Combo1(3).Clear
                    Combo1(3).AddItem mrcc.Fields(7)
                    Combo1(3).ListIndex = 0
                ElseIf Trim(Combo1(2)) = "公务舱" Then
                    Combo1(3).Clear
                    Combo1(3).AddItem mrcc.Fields(8)
                    Combo1(3).ListIndex = 0
                Else
                    Combo1(3).Clear
                    Combo1(3).AddItem mrcc.Fields(9)
                    Combo1(3).ListIndex = 0
                End If
            End If
            ‘关闭数据集对象
            mrcc.Close
            ‘选择制定客机编号的有关信息
            txtSQL = "select * from planeInfo where planeNO = '" & Trim(ticketCsum) & "'"
            Set mrcc = ExecuteSQL(txtSQL, MsgText)
            ‘判断数据集对象是否为空
            If Not mrcc.EOF Then
                ticketCsum = mrcc.Fields(4)
                ticketMsum = mrcc.Fields(5)
                ticketFsum = mrcc.Fields(6)

            End If
            ‘关闭数据集对象
            mrcc.Close
        End If
    ElseIf Index = 4 Then
        ‘选择相应客户姓名的记录
        txtSQL = "select customerNO,customerType from customerInfo where customerName = '" & Trim(Combo1(4)) & "'"
        Set mrcc = ExecuteSQL(txtSQL, MsgText)
       ‘判断数据集对象是否为空
        If Not mrcc.EOF Then
            txtcustomer = mrcc.Fields(0)
            Combo1(5).Clear
            Combo1(5).AddItem mrcc.Fields(1)
            Combo1(5).ListIndex = 0
            ‘选择客户对应的客户类型
            txtSQL = "select distinct discount from customerType where ctypeName = '" & Trim(Combo1(5)) & "'"
            Set mrcd = ExecuteSQL(txtSQL, MsgText)
           ‘判断数据集对象是否为空
            If Not mrcd.EOF Then
                Combo1(6).Clear
                Combo1(6).AddItem mrcd.Fields(0)
                Combo1(6).ListIndex = 0
            End If
           ‘关闭数据集对象
            mrcd.Close
        End If
       ‘关闭数据集对象
        mrcc.Close
           
    End If
End Sub
选择航线信息和客户信息后，输入机票日期，单击“保存”按钮，订票信息保存到数据库中。除了对数据格式的检查，还要检查相应航班是否满员。代码如下：
Private Sub cmdSave_Click()
    Dim intCount As Integer
    Dim sMeg As String
    Dim MsgText As String

    ‘判断列表框中内容是否为空
    For intCount = 0 To 6
        If Trim(Combo1(intCount) & " ") = "" Then
            Select Case intCount
                Case 0
                    sMeg = "出发城市"
                Case 1
                    sMeg = "到达城市"
                Case 2
                    sMeg = "舱位类型"
                Case 3
                    sMeg = ""
                Case 4
                    sMeg = "顾客姓名"
                Case 5
                    sMeg = ""
                Case 6
                    sMeg = ""
            End Select
            sMeg = sMeg & "不能为空！"
            MsgBox sMeg, vbOKOnly + vbExclamation, "警告"
            Combo1(intCount).SetFocus
            Exit Sub
        End If
    Next intCount
    ‘判断机票日期是否输入
    If Trim(txtItem(0)) = "" Then
        sMeg = "出发日期不能为空！"
        MsgBox sMeg, vbOKOnly + vbExclamation, "警告"
        txtItem(0).SetFocus
        Exit Sub
    End If
    ‘判断输入机票日期是否为日期型数据
    If IsDate(txtItem(0)) Then
        txtItem(0) = Format(txtItem(0), "yyyy-mm-dd")
    Else
        MsgBox "时间应输入日期（yyyy-mm-dd）！", vbOKOnly + vbExclamation, "警告"
        txtItem(0).SetFocus
        Exit Sub

    End If
    '判断是否有相同内容的记录
    txtSQL = "select * from ticketInfo where ticketNO<>'" & Trim(txtticket) & "' and customerNO ='" & Trim(txtcustomer) & "' and ticketDate = '" & Trim(txtItem(0)) & "'"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    If mrc.EOF = False Then
        MsgBox "已经存在相同顾客订票的记录！", vbOKOnly + vbExclamation, "警告"
        txtItem(1).SetFocus
        Exit Sub
    End If
    '先删除已有记录
    txtSQL = "delete from ticketInfo where ticketNO='" & Trim(txtticket) & "'"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    '判断航班是否满员
    txtSQL = "select * from ticketInfo where airlineNO = '" & Trim(txtairline) & " ' and ticketDate = '" & Trim(txtItem(0)) & "' and serviceType = '" & Trim(Combo1(2)) & "'"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    ‘判断数据集对象是否为空
    If Not mrc.EOF Then
        If Combo1(2) = "经济舱" Then
            If mrc.RecordCount > (ticketCsum - 1) Then
                MsgBox "对不起，该航班经济舱已经满员", vbOKOnly + vbExclamation, "警告"
                Exit Sub
            End If
        ElseIf Combo1(2) = "公务舱" Then
            If mrc.RecordCount > (ticketMsum - 1) Then
                MsgBox "对不起，该航班公务舱已经满员", vbOKOnly + vbExclamation, "警告"
                Exit Sub
            End If
        Else
            If mrc.RecordCount > (ticketFsum - 1) Then
                MsgBox "对不起，该航班头等舱已经满员", vbOKOnly + vbExclamation, "警告"
                Exit Sub
            End If
        End If
    End If
    ‘关闭数据集对象
    mrc.Close
    '再加入新记录

    txtSQL = "select * from ticketInfo"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    mrc.AddNew
    mrc.Fields(0) = txtticket
    mrc.Fields(1) = txtcustomer
    For intCount = 2 To 4
        mrc.Fields(intCount) = Trim(Combo1(intCount + 2))
    Next intCount
    mrc.Fields(5) = txtairline
    For intCount = 6 To 7
        mrc.Fields(intCount) = Trim(Combo1(intCount - 6))
    Next intCount
    mrc.Fields(8) = Trim(txtItem(0))
    For intCount = 9 To 10
        mrc.Fields(intCount) = Trim(Combo1(intCount - 7))
    Next intCount
    mrc.Fields(11) = Trim(Combo1(3) * Combo1(6) / 100)
    mrc.Fields(12) = txtItem(1)
    ‘更新数据集
    mrc.Update
    ‘关闭数据集对象
    mrc.Close
    If gintKmode = 1 Then
        MsgBox "订票成功！航班为" & Trim(txtItem(0)) & "从" & Trim(Combo1(0)) & "到" & Trim(Combo1(1)) & "的" & Trim(Combo1(2)) & "机票，票价为" & Trim(Combo1(3) * Combo1(6) / 100) & "元！", vbOKOnly + vbExclamation, "订票记录"
        For intCount = 0 To 1
            txtItem(intCount) = ""
        Next intCount
        mblChange = False
        ‘重新显示机票信息
        Unload frmTicket
        frmTicket.txtSQL = "select * from ticketInfo"
        frmTicket.Show
    ElseIf gintKmode = 2 Then
        MsgBox "修改订票信息成功！修改后的航班为" & Trim(txtItem(0)) & "从" & Trim(Combo1(0)) & "到" & Trim(Combo1(1)) & "的" & Trim(Combo1(2)) & "机票，票价为" & Trim(Combo1(3) * Combo1(6) / 100) & "元！", vbOKOnly + vbExclamation, "订票记录"
        Unload Me
       ‘重新显示机票信息
        Unload frmTicket
        frmTicket.txtSQL = "select * from ticketInfo"
        frmTicket.Show
    End If
End Sub
11.3 修改订票信息
在机票信息列表中选择需要修改的记录，然后单击“修改”按钮，当前记录将出现在如图9-19所示的窗体中。修改完毕，单击“保存”按钮，修改后的记录保存到数据库中。
11.4 删除订票信息
选择机票信息列表中需要删除的记录，然后单击“删除”按钮，可以删除所选记录。
11.5 查询订票信息
在如图9-25所示的机票信息列表中，单击“查询”按钮，出现如图9-27所示的对话框。

图9-27 机票信息查询窗体
窗体载入时自动在列表框中添加出发城市、到达城市和舱位类型的信息，代码如下：
Private Sub Form_Load()
    Dim i As Integer
    Dim sSql As String
    Dim txtSQL As String
    Dim MsgText As String
    Dim mrc As ADODB.Recordset
    ‘清除列表框中内容
    For i = 0 To 2
        Combo1(i).Clear
    Next i
    ‘选择所有与出发城市有关的信息
    txtSQL = "select distinct departCity from airlineInfo "
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    ‘判断数据集对象是否为空
    If Not mrc.EOF Then
        Do While Not mrc.EOF
            Combo1(0).AddItem mrc.Fields(0)
            mrc.MoveNext
        Loop
    End If
    ‘关闭数据集对象
    mrc.Close
    ‘选择所有与到达城市有关的信息
    txtSQL = "select distinct arrivalCity from airlineInfo"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    ‘判断数据集对象是否为空
    If Not mrc.EOF Then
        Do While Not mrc.EOF
            Combo1(1).AddItem mrc.Fields(0)
            mrc.MoveNext
        Loop
    End If
    mrc.Close
    ‘选择所有与舱位类型有关的信息
    txtSQL = "select distinct serviceName from serviceInfo"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
    ‘判断数据集对象是否为空
    If Not mrc.EOF Then
        Do While Not mrc.EOF
            Combo1(2).AddItem mrc.Fields(0)
            mrc.MoveNext
        Loop
    End If
    mrc.Close
End Sub
输入查询内容完毕，单击“确定”按钮将自动组合产生查询语句。满足查询条件的记录显示在如图9-25所示的机票信息列表中，代码如下：
Private Sub cmdOK_Click()
    Dim txtSQL As String
    Dim MsgText As String
    Dim mrc As ADODB.Recordset
    Dim intCount As Integer
    Dim sMeg As String

    Dim i, j, k
    ‘判断是否选择相应信息
    For intCount = 0 To 1
        If Trim(Combo1(intCount) & " ") = "" Then
            Select Case intCount
                Case 0
                    sMeg = "出发城市"
                Case 1
                    sMeg = "到达城市"
            End Select
            sMeg = sMeg & "不能为空！"
            MsgBox sMeg, vbOKOnly + vbExclamation, "警告"
            Combo1(intCount).SetFocus
            Exit Sub
        End If
    Next intCount
    ‘判断是否输入查询日期
    If Trim(txtItem(0)) = "" Then
        sMeg = "出发日期不能为空！"
        MsgBox sMeg, vbOKOnly + vbExclamation, "警告"
        txtItem(0).SetFocus
        Exit Sub
    End If
    ‘判断输入查询日期是否为日期型数据
    If IsDate(txtItem(0)) Then
        txtItem(0) = Format(txtItem(0), "yyyy-mm-dd")
    Else
        MsgBox "时间应输入日期（yyyy-mm-dd）！", vbOKOnly + vbExclamation, "警告"
        txtItem(0).SetFocus
        Exit Sub
    End If
    ‘判断是否输入舱位类型
    If Not (Trim(Combo1(2)) = "") Then
        txtSQL = "select * from ticketInfo where ticketDate = '" & Trim(txtItem(0)) & "' and departCity = '" & Trim(Combo1(0)) & "' and arrivalCity = '" & Trim(Combo1(1)) & "' and serviceType = '" & Trim(Combo1(2)) & "'"
      ‘执行查询语句
        Set mrc = ExecuteSQL(txtSQL, MsgText)
       ‘计算经济舱剩余机票数量
        If Trim(Combo1(2)) = "经济舱" Then
            intCount = ticketCsum - mrc.RecordCount
       ‘计算公务舱剩余机票数量
        ElseIf Trim(Combo1(2)) = "公务舱" Then
            intCount = ticketMsum - mrc.RecordCount
        Else
            intCount = ticketFsum - mrc.RecordCount
        End If
       ‘判断机票剩余数量
        If intCount > 0 Then
            MsgBox Trim(txtItem(0)) & "从" & Trim(Combo1(0)) & "到" & Trim(Combo1(1)) & Trim(Combo1(2)) & "的机票还有" & intCount & "张!", vbOKOnly + vbExclamation, "机票信息"
        Else
            MsgBox "对不起," & Trim(txtItem(0)) & "从" & Trim(Combo1(0)) & "到" & Trim(Combo1(1)) & Trim(Combo1(2)) & "的航班已经满员，请预定其他航班！", vbOKOnly + vbExclamation, "机票信息"
        End If
    Else
        txtSQL = "select * from ticketInfo where ticketDate = '" & Trim(txtItem(0)) & "' and departCity = '" & Trim(Combo1(0)) & "' and arrivalCity = '" & Trim(Combo1(1)) & "' and serviceType = '经济舱'"
       ‘执行查询语句
        Set mrc = ExecuteSQL(txtSQL, MsgText)
        i = mrc.RecordCount
       ‘关闭数据集对象
        mrc.Close
        txtSQL = "select * from ticketInfo where ticketDate = '" & Trim(txtItem(0)) & "' and departCity = '" & Trim(Combo1(0)) & "' and arrivalCity = '" & Trim(Combo1(1)) & "' and serviceType = '公务舱'"
        Set mrc = ExecuteSQL(txtSQL, MsgText)
        ‘关闭数据集对象
        mrc.Close
        ‘查询头等舱座位数量
        txtSQL = "select * from ticketInfo where ticketDate = '" & Trim(txtItem(0)) & "' and departCity = '" & Trim(Combo1(0)) & "' and arrivalCity = '" & Trim(Combo1(1)) & "' and serviceType = '头等舱'"
        Set mrc = ExecuteSQL(txtSQL, MsgText)
        k = mrc.RecordCount
        mrc.Close
        MsgBox Trim(txtItem(0)) & "从" & Trim(Combo1(0)) & "到" & Trim(Combo1(1)) & "经济舱的机票还有" & (ticketCsum - i) & "张,公务舱的机票还有" & (ticketMsum - j) & "张，头等舱的机票还有" & (ticketFsum - k) & "张！", vbOKOnly + vbExclamation, "机票信息"

    End If
    Unload Me
End Sub
12 系统的实现
现在已经完成了程序各个功能模块的创建，现在来运行整个系统。运行程序，出现如图9-28所示的登录窗口。

图9-28 用户登录窗口
输入用户名和密码后，进入系统。选择“航线信息管理|舱位信息”菜单，出现如图9-29所示的窗体。

图9-29 显示舱位信息窗体
选择“航线信息管理|客机信息”菜单，将显示所有客机信息，如图9-30所示。

图9-30 显示客机信息的窗体
在客机信息列表中单击“添加”按钮，出现如图9-31所示的窗体，在其中输入客机信息。

图9-31 添加客机信息
选择“航线信息管理|航线信息”菜单，出现如图9-32所示的航线信息列表。

图9-32 航线信息列表
在航线信息列表中单击“添加”按钮，并输入航线内容，如图9-33所示。

图9-33 添加航线信息
在航线信息列表中单击“查询”按钮，并设置查询内容，如图9-34所示。

图9-34 查询航线信息窗体
航线查询结果如图9-35所示。

图9-35 航线信息查询结果
选择“客户信息管理|客户信息”菜单，并输入客户信息，如图9-36所示。

图9-36 添加客户信息
选择“订票信息管理|订票信息”菜单，出现如图9-37所示的机票信息列表。

图9-37 机票信息列表
在机票信息列表中单击“添加”按钮，出现如图9-38所示的窗体，输入订票信息。

图9-38 添加订票信息
单击“保存”按钮，出现如图9-39所示的对话框提示订票成功。

图9-39 订票提示信息
在机票信息列表中，单击“查询”按钮，出现如图9-40所示的窗体，输入查询内容，可以得到剩余机票信息。

图9-40 机票信息查询窗体
查询结果如图9-41所示。

图9-41 机票信息查询结果
13 系统的编译和发行
完成了航空公司管理信息系统的编程和调试工作，最后一步就是该系统的编译和发行。这涉及到工程项目属性的设置、可执行应用程序的生成。
在系统的编译和发行以前，需要设置工程项目的属性。选择“Project|MIS_TICKET Properties”菜单，进行属性设置，如图9-42所示。
最后选择“File|Make MIS_TICKET.exe”菜单，编译开始。编译完毕后，即生成了相应的可执行文件。编译通过后，生成可执行文件Mis_TICKET.exe。我们需要在发行前对生成的可执行文件进行测试。通过测试的可执行文件，就可以进行发布了。

图9-42 进行项目的属性设置
14 小结
一个完整的航空公司管理信息系统就创建完毕了。在本设计中我们详细地讲述了该航空公司管理信息系统的系统设计部分，包括功能模块设计、数据库结构设计等。系统设计为整个程序构建了骨架，各个功能模块实现各个细节部分。

相关论文